Gave up adapter to old libisofs. Renaming libisoburn and xorriso dirs.

libisoburn/trunk/xorriso/configure_ac.txt

@@ -0,0 +1,93 @@
+AC_INIT([xorriso], [0.1.0], [http://libburnia-project.org])
+AC_PREREQ([2.50])
+dnl AC_CONFIG_HEADER([config.h])	
+
+AC_CANONICAL_HOST
+AC_CANONICAL_TARGET
+
+AM_INIT_AUTOMAKE([subdir-objects])
+
+dnl A dummy demanded by libburn sources, but unused by xorriso
+BURN_MAJOR_VERSION=0
+BURN_MINOR_VERSION=0
+BURN_MICRO_VERSION=0
+AC_SUBST(BURN_MAJOR_VERSION)
+AC_SUBST(BURN_MINOR_VERSION)
+AC_SUBST(BURN_MICRO_VERSION)
+
+
+AC_PREFIX_DEFAULT([/usr/local])
+test "$prefix" = "NONE" && prefix=$ac_default_prefix
+
+AM_MAINTAINER_MODE
+
+AM_PROG_CC_C_O
+AC_C_CONST
+AC_C_INLINE
+AC_C_BIGENDIAN
+
+dnl Large file support
+AC_SYS_LARGEFILE
+AC_FUNC_FSEEKO
+AC_CHECK_FUNC([fseeko])
+if test ! $ac_cv_func_fseeko; then
+   AC_ERROR([Libburn requires largefile support.])
+fi
+
+AC_PROG_LIBTOOL
+AC_SUBST(LIBTOOL_DEPS)
+LIBTOOL="$LIBTOOL --silent"
+
+AC_PROG_INSTALL
+
+AC_CHECK_HEADERS()
+
+AC_CHECK_MEMBER([struct tm.tm_gmtoff],
+	[AC_DEFINE(HAVE_TM_GMTOFF, 1,
+		[Define this if tm structure includes a tm_gmtoff entry.])],
+	,
+	[#include <time.h>])
+
+THREAD_LIBS=-lpthread
+AC_SUBST(THREAD_LIBS)
+
+TARGET_SHIZZLE
+AC_SUBST(ARCH)
+AC_SUBST(LIBBURN_ARCH_LIBS)
+
+dnl Add compiler-specific flags
+
+dnl See if the user wants aggressive optimizations of the code
+AC_ARG_ENABLE(debug,
+[  --enable-debug          Disable aggressive optimizations [default=yes]],
+              , enable_debug=yes)
+if test x$enable_debug != xyes; then
+    if test x$GCC = xyes; then
+        CFLAGS="$CFLAGS -O3"
+        CFLAGS="$CFLAGS -fexpensive-optimizations"
+    fi
+    CFLAGS="$CFLAGS -DNDEBUG"
+else
+    if test x$GCC = xyes; then
+        CFLAGS="$CFLAGS -g -pedantic -Wall"
+    fi
+    CFLAGS="$CFLAGS -DDEBUG"
+fi
+
+
+dnl Check whether there is readline-devel and readline-runtime.
+dnl If not, erase this macro which would enable use of readline(),add_history()
+READLINE_DEF="-DXorriso_with_readlinE"
+dnl The empty yes case obviously causes -lreadline to be linked
+AC_CHECK_HEADER(readline/readline.h, AC_CHECK_LIB(readline, readline, , READLINE_DEF= ), READLINE_DEF= )
+dnl The X= in the yes case prevents that -lreadline gets linked twice
+AC_CHECK_HEADER(readline/history.h, AC_CHECK_LIB(readline, add_history, X= , READLINE_DEF= ), READLINE_DEF= )
+AC_SUBST(READLINE_DEF)
+
+
+AC_CONFIG_FILES([
+	Makefile
+	version.h
+	xorriso.pc
+	])
+AC_OUTPUT